戻る

作成したVBSファイルの名前のつけ方は前ページと一緒。
右側14文字が FAX番号10桁.vbs になるようにしてください。
(XXX_0120999876.vbs)


Option Explicit
Dim MyArgs
Dim MyStrSendFile, MyStrFAXNum, MyStrWinVer, MyStrPC
Dim MyFaxServer, MyFaxDoc
On Error Resume Next
Set MyArgs = WScript.Arguments
MyStrSendFile = MyArgs(0)
Set MyArgs = Nothing
If MyStrSendFile = "" Then
    MsgBox "何かファイルをDragDropしろって", vbOKOnly, "ダブルクリックじゃなく"
    WScript.Quit
End If
MyStrFAXNum = Left(Right(WScript.ScriptFullName, 14), 10)
If IsNumeric(MyStrFAXNum) = False Then
    MsgBox "数字以外の文字が入ったFAXナンバーなんて絶対変"
    WScript.Quit
End If
MyStrWinVer = CreateObject("Wscript.Shell").RegRead("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\CurrentVersion")
MyStrPC = CreateObject("WScript.Network").ComputerName
If MyStrWinVer = "5.0" Then
    Set MyFaxServer = CreateObject("FaxServer.FaxServer")
    MyFaxServer.Connect MyStrPC
    Set MyFaxDoc = MyFaxServer.CreateDocument("FaxDocument")
    MyFaxDoc.filename = MyStrSendFile
    MyFaxDoc.FaxNumber = MyStrFAXNum
    MyFaxDoc.Send
    MyFaxServer.Disconnect
Else
    Set MyFaxServer = CreateObject("FAXCOMEX.FaxServer")
    MyFaxServer.Connect MyStrPC
    Set MyFaxDoc = CreateObject("FAXCOMEX.FaxDocument")
    MyFaxDoc.Recipients.Add MyStrFAXNum
    MyFaxDoc.Body = MyStrSendFile
    MyFaxDoc.ConnectedSubmit MyFaxServer
    MyFaxServer.Disconnect
End If
Set MyFaxDoc = Nothing
Set MyFaxServer = Nothing

どうせ分かりきったマシンでしか使わないからWindowsのバージョンに関する分岐処理なんていらない、エラーメッセージもいらない、ということなら更に短く出来ます。
 
Option Explicit
Dim MyArgs
Dim MyStrSendFile, MyStrFAXNum, MyStrPC
Dim MyFaxServer, MyFaxDoc
On Error Resume Next
Set MyArgs = WScript.Arguments
MyStrSendFile = MyArgs(0)
Set MyArgs = Nothing
If MyStrSendFile <> "" Then
    MyStrFAXNum = Left(Right(WScript.ScriptFullName, 14), 10)
    If IsNumeric(MyStrFAXNum) = True Then
        MyStrPC = CreateObject("WScript.Network").ComputerName
        Set MyFaxServer = CreateObject("FAXCOMEX.FaxServer")
        MyFaxServer.Connect MyStrPC
        Set MyFaxDoc = CreateObject("FAXCOMEX.FaxDocument")
        MyFaxDoc.Recipients.Add MyStrFAXNum
        MyFaxDoc.Body = MyStrSendFile
        MyFaxDoc.ConnectedSubmit MyFaxServer
        MyFaxServer.Disconnect
        Set MyFaxDoc = Nothing
        Set MyFaxServer = Nothing
    End If
End If